Sub TickerTotalVolume()

Const TickerColumn As Integer = 9

Const YearlyChangeColumn As Integer = 10

Const PercentChangeColumn As Integer = 11

Const TotalColumn As Integer = 12

Const SummaryLabelColumn As Integer = 15

Const SummaryTickerColumn As Integer = 16

Const SummaryValueColumn As Integer = 17

Dim Ticker As String

Dim Year As String

Dim Volume As Double

Dim i As Long

Dim ws As Worksheet

Dim LastRow As Long

Dim j As Integer

Dim OpenPrice As Double

Dim ClosePrice As Double

Dim PriceChange As Double

Dim GreatestIncreaseTicker As String

Dim GreatestDecreaseTicker As String

Dim GreatestTotalVolumeTicker As String

Dim GreatestPercentIncreaseValue As Double

Dim GreatestPercentDecreaseValue As Double

Dim GreatestTotalVolumeValue As Double

For Each ws In Worksheets

'Setting all my headers on all the worksheets

ws.Cells(1, TickerColumn).Value = "Ticker"

ws.Cells(1, YearlyChangeColumn).Value = "Yearly Change"

ws.Cells(1, PercentChangeColumn).Value = "Percent Change"

ws.Cells(1, TotalColumn).Value = "Total Stock Volume"

ws.Cells(2, SummaryLabelColumn).Value = "Greatest % Increase"

ws.Cells(3, SummaryLabelColumn).Value = "Greatest % Decrease"

ws.Cells(4, SummaryLabelColumn).Value = "Greatest Total Volume"

ws.Cells(1, SummaryTickerColumn).Value = "Ticker"

ws.Cells(1, SummaryValueColumn).Value = "Value"

' Initialized variables

Volume = 0

j = 2

GreatestPercentDecreaseValue = 10

GreatestPercentIncreaseValue = 0

GreatestTotalVolumeValue = 0

LastRow = ws.Cells(Rows.Count, 1).End(xlUp).Row

OpenPrice = ws.Cells(2, 3).Value

' Loop thru each row

For i = 2 To LastRow

Ticker = ws.Cells(i, 1).Value

Volume = Volume + ws.Cells(i, 7).Value

' Evaluate if ticker has changed

If (Ticker <> ws.Cells(i + 1, 1).Value) Then

ws.Cells(j, TickerColumn).Value = Ticker

ws.Cells(j, TotalColumn).Value = Volume

' Setting the close price

ClosePrice = ws.Cells(i, 6).Value

' Calculating price change

PriceChange = ClosePrice - OpenPrice

ws.Cells(j, YearlyChangeColumn).Value = PriceChange

ws.Cells(j, PercentChangeColumn).NumberFormat = "0.00%"

If (PriceChange = 0 Or OpenPrice = 0) Then

ws.Cells(j, PercentChangeColumn).Value = 0

Else

' Searching the greatest % Decrease Value within each ticker

ws.Cells(j, PercentChangeColumn).Value = PriceChange / OpenPrice

If ((PriceChange / OpenPrice) > GreatestPercentIncreaseValue) Then

GreatestPercentIncreaseValue = PriceChange / OpenPrice

GreatestIncreaseTicker = Ticker

End If

' Searching the greatest % Decrease Value within each ticker

If ((PriceChange / OpenPrice) < GreatestPercentDecreaseValue) Then

GreatestPercentDecreaseValue = PriceChange / OpenPrice

GreatestDecreaseTicker = Ticker

End If

' Searching the highest volume within each ticker

If (Volume > GreatestTotalVolumeValue) Then

GreatestTotalVolumeValue = Volume

GreatestTotalVolumeTicker = Ticker

End If

End If

' Setting conditional formatting where number 3 is green and 4 is red

If (PriceChange < 0) Then

ws.Cells(j, YearlyChangeColumn).Interior.ColorIndex = 3

Else

ws.Cells(j, YearlyChangeColumn).Interior.ColorIndex = 4

End If

' Set open price to the next row open price column

OpenPrice = ws.Cells(i + 1, 3).Value

Volume = 0

j = j + 1

End If

Next i

' Setting the values for the summary section of each worksheet

ws.Cells(2, SummaryTickerColumn).Value = GreatestIncreaseTicker

ws.Cells(3, SummaryTickerColumn).Value = GreatestDecreaseTicker

ws.Cells(4, SummaryTickerColumn).Value = GreatestTotalVolumeTicker

ws.Cells(2, SummaryValueColumn).Value = GreatestPercentIncreaseValue

ws.Cells(3, SummaryValueColumn).Value = GreatestPercentDecreaseValue

ws.Cells(4, SummaryValueColumn).Value = GreatestTotalVolumeValue

ws.Cells(2, SummaryValueColumn).NumberFormat = "0.00%"

ws.Cells(3, SummaryValueColumn).NumberFormat = "0.00%"

ws.Columns("J:Q").AutoFit

Next

End Sub